The IDL procedure t3dset

pro t3dset,rlo,rhi,ax=ax,ay=ay,az=az,per=per,scale=scale, len=len
;
;  make a t3d setup for a given box of data
;
; done by Klaus Galsgaard
;
	if n_params() eq 0 then begin
		print,'t3dset,rlo,rhi,ax=ax,ay=ay,az=az,per=per'
		print,'rlo,rhi : lower and upper boundary for box'
		print,'ax,ay,az : the wanted view angle'
		print,'per      : perspektiv distance'
		print,'scale	: scale of plot'
		print,'len      : length that the plot is moved
		return
	endif

	if keyword_set(ax)    eq 0 and n_elements(ax) eq 0 then ax=30
	if keyword_set(ay)    eq 0 and n_elements(ay) eq 0 then ay=0
	if keyword_set(az)    eq 0 and n_elements(az) eq 0 then az=30
	if keyword_set(per)   eq 0 then per=30
	if keyword_set(scale) eq 0 then scale=.57
	if keyword_set(len)   eq 0 then len=.5

        !x.s=[-rlo(0),1.]/(rhi(0)-rlo(0))
        !y.s=[-rlo(1),1.]/(rhi(1)-rlo(1))
        !z.s=[-rlo(2),1.]/(rhi(2)-rlo(2))

        u=[1,1,1]

        t3d,/reset,tr=-len*u
	t3d,rot=[0,ay,0]
        t3d,rot=[0,0,az]
        t3d,rot=[ax-90,0,0]
        t3d,sc=scale*u
	t3d,per=per
        t3d,tr=len*u

end